Bucles

Repetir un número de veces

repetir 3 veces {
  imprimir("¡hola!")
}

repetir n veces evalúa n una sola vez, al empezar. Tiene que ser un entero, 0 o más.

Contar desde … hasta

Para contar, para … desde … hasta le pone nombre a cada número. Incluye los dos extremos:

para i desde 1 hasta 5 {
  imprimir(i)
}

Con con_paso se cuenta de otra forma, también hacia atrás:

para i desde 10 hasta 0 con_paso -5 {
  imprimir(i)
}

• La variable (i) es nueva en cada vuelta y solo existe dentro del bucle.
• Los límites y el paso se calculan una sola vez, al empezar.

Mientras se cumpla

mientras revisa la condición antes de cada vuelta:

variable i = 0
mientras (i es_menor_que 3) {
  imprimir(i)
  i = i + 1
}

Hasta que se cumpla

hacer … hasta_que ejecuta el bloque al menos una vez y repite hasta que la condición sea verdadera:

variable cuenta = 3
hacer {
  imprimir(cuenta)
  cuenta = cuenta - 1
} hasta_que (cuenta es_igual_a 0)

Para cada elemento

para_cada recorre una lista o un texto:

para_cada fruta en ["mango", "piña"] {
  imprimir(fruta)
}

para_cada letra en "hola" {
  imprimir(letra)
}

Romper y continuar

romper sale del bucle más cercano; continuar salta a su siguiente vuelta:

para n desde 1 hasta 10 {
  si (n mod 2 es_igual_a 0) {
    continuar
  }
  si (n es_mayor_que 7) {
    romper
  }
  imprimir(n)
}

Un bucle que no termina

Si la condición nunca deja de cumplirse, el bucle sigue para siempre. En el sandbox puedes pausarlo; la página no se congela. Fuera del sandbox, la ejecución se detiene al pasar el límite de operaciones.

Si vienes de otro lenguaje y buscas el for de tres partes, está en el puente hacia otros lenguajes.